f[λ_]=BesselJ[1,λ];
Plot[ f'[λ],{λ, 0, 34},
AxesLabel->{"λ","(Subscript[J, 1])'"}
]
λs= λ/.FindRoot[ f'[λ]==0, {λ, {2,5,8.5,12,15}}]

Plot[
Evaluate[
 Table[
BesselJ[1, λs[[i]] x],
{i,1,5}]
], {x, 0,1},
PlotLegends->Automatic]

2×2 Symmetric Matrices

A= (({{3, -1}, {-1, 1.1}}));
{λ1,λ2}=Eigenvalues[A]
{v1,v2}=Eigenvectors[A];
ParametricPlot[ 
{
{Cos[t], Sin[t]},
A.{Cos[t], Sin[t]}
}
,
{t, 0, 2π},
Epilog->{Black,
Arrow[ {{0,0},λ1 v1}],
Arrow[ {{0,0},λ2 v2}],
Cyan,
Table[ {Hue[(t/(2π))],Arrow[ {{Cos[t],Sin[t]},A.{Cos[t],Sin[t]}}]},{t,0, 2π,2π/24}]
}
]

3×3 Symmetric Matrices

A= (({{1., 0.5, 0.1}, {0.5, 1.3, 0.1}, {0.1, 0.1, 1.2}}));
{λ1,λ2,λ3}=Eigenvalues[A]
{v1,v2,v3}=Eigenvectors[A];
Show[
ParametricPlot3D[ 
{
{Cos[t]Sin[ϕ], Sin[t]Sin[ϕ], Cos[ϕ]},
A.{Cos[t]Sin[ϕ], Sin[t]Sin[ϕ], Cos[ϕ]}
},
{t, 0, 2π},
{ϕ, 0, π},
PlotStyle->Opacity[0.1]
],
Graphics3D[ {
{Red, Arrow[{{0,0,0},λ1 v1}]},
{Blue, Arrow[{{0,0,0},λ2 v2}]},
{Green, Arrow[{{0,0,0},λ3 v3}]}
}]
]

n×n Symmetric Matrices

A real n×n symmetric matrix has n real eigenvalues and n orthogonal eigenvectors.   This means that 
	A=Q.Λ.Transpose[Q]
where Λ=(({{ (Subscript[λ, 1])    ,   0    ,   0    ,   0    ,   0    }, {  0    ,   (Subscript[λ, 2])    ,   0    ,   0    ,   0    }, {  ⋮    ,   ⋱    ,   ⋱   ,  ⋱    ,   ⋮ }, {  0    ,   0    ,   0    ,   (Subscript[λ, n-1])    ,   0    }, {  0    ,   0    ,   0    ,   0    ,   (Subscript[λ, n])    }}))
and Q=(({{(Subscript[v, 1]), (Subscript[v, 2]), ⋯, (Subscript[v, n-1]), (Subscript[v, n])}})).

This is a very concrete statement.

n=4;
A=RandomReal[{-1,1},{n,n}];
A=A+Transpose[A];
{λs,vs}=Eigensystem[A];
MatrixForm[A]
MatrixForm[Transpose[vs].DiagonalMatrix[λs].vs]

A real n×n matrix satisfying (Q^T).Q=(Subscript[Id, n]) is called an orthogonal matrix and has all of its eigenvalues equal to one in magnitude.  If it has determinant one it is a rotation.

2×2 Skew Matrices

A= (({{0, -2}, {2, 0}}));
{λ1,λ2}=Eigenvalues[A]
{v1,v2}=Eigenvectors[A]
ParametricPlot[ 
{
{Cos[t], Sin[t]},
A.{Cos[t], Sin[t]}
}
,
{t, 0, 2π},
Epilog->{
{Black,Thickness[0.01],Arrow[ {{0,0},Re[ v1]}],Arrow[ {{0,0},Im[ v1]}]},
Table[ {Hue[(t/(2π))],
Arrow[ {{Cos[t],Sin[t]},A.{Cos[t],Sin[t]}}]
},{t,0, 2π,2π/24}]
}
]

2×2 Rotation Matrices

θ=0.1;
A= (({{Cos[θ], -Sin[θ]}, {Sin[θ], Cos[θ]}}));
MatrixForm[A]
{λ1,λ2}=Eigenvalues[A]
{v1,v2}=Eigenvectors[A];
ParametricPlot[ 
{
{Cos[t], Sin[t]},
A.{Cos[t], Sin[t]}
}
,
{t, 0, 2π},
Epilog->{
{Black,Thickness[0.01],Arrow[ {{0,0},Re[ v1]}],Arrow[ {{0,0},Im[ v1]}]},
Table[ {Hue[(t/(2π))],
Arrow[ {{Cos[t],Sin[t]},A.{Cos[t],Sin[t]}}]
},{t,0, 2π,2π/24}]
}
]

Polar Decomposition

Any real matrix can be written as the product of an orthogonal matrix with eigenvalues of magnitude 1 (which is a rotation or reflection) and a symmetric matrix.  The recipe is pretty simple for an invertible matrix A.
	A=R.S
where S=(Sqrt[A.(A^T)]) and R=A.(S^(-1)).

The prinicpal square root of a positive definate matrix P is Q.(Sqrt[Λ]).(Q^T)  where Q is the orthogonal eigenvector matrix and 
	(Sqrt[Λ])=(({{ +(Sqrt[(Subscript[λ, 1])])    ,   0    ,   0    ,   0    ,   0    }, {  0    , +(Sqrt[(Subscript[λ, 2])])   ,   0    ,   0    ,   0    }, {  ⋮    ,   ⋱    ,   ⋱   ,  ⋱    ,   ⋮ }, {  0    ,   0    ,   0    ,   +(Sqrt[(Subscript[λ, n-1])])    ,   0    }, {  0    ,   0    ,   0    ,   0    ,  +(Sqrt[(Subscript[λ, n])])    }}))

Pretty clear A is symmetric i.e. A=(A^T).  The recipe does not change if you take the transpose.

Pretty clear R is orthogonal.  (R^T)=(S^(-T)).(A^T)  so (R^T).R=(S^(-T)).(A^T).A.(S^(-1))=(S^(-1)).S.S.(S^(-1))

Lets see this in action

n=3;
A=RandomReal[{-1,1},{n,n}];
P= MatrixPower[A.Transpose[A],1/2];
U=A.Inverse[P];
MatrixForm[P]
Eigenvalues[P]
Eigenvalues[U]