The Disk Method

Manipulate[
Show[{
Graphics3D[{
If[sec,{Text[Style["x",Italic],{t0,0,-.15}],Line[{{t0,0,-.04},{t0,0,.04}}]},{}],
If[revvol,{{Black,Text[Row[{"volume of the solid = (∫_a^b)","π ",Style["f",Italic],"(",Style["x",Italic],Superscript[")","2 "],Style["dx",Italic]}],{2.5,0,.25Sin[6.]+2.5}]},{Red,Thick,Line[{{t0,0,0},{t0,0,.25Sin[2t0+1]+1}}]}},{}],
If[revarea,{{Darker[Orange],Text[Row[{"area = π ",Style["f",Italic],"(",Style["x",Italic],Superscript[")",2]}],{t0,0,.25Sin[2t0+1]+1.85}]},{Red,Thick,Line[{{t0,0,0},{t0,0,.25Sin[2t0+1]+1}}]}},{}],
{Text[Row[{Style["y",Italic]," = ",Style["f",Italic],"(",Style["x",Italic],")"}],{4.45,0,1.2}],
If[t0==1||t0≥1.35,Text[Style["a",Italic],{.95,0,-.15}],{}],
Text[Style["b",Italic],{4,0,-.15}],
Text[Style["x",Italic],{4.55,0,0}],
Text[Style["y",Italic],{0,0,2.6}]},
{RGBColor[0,0,0],Line[{{0,0,0},{5,0,0}}],Line[{{0,0,-4},{0,0,4}}]},
leftend,rightend,
Line[{{1,0,-.04},{1,0,.04}}],
Line[{{4,0,-.04},{4,0,.04}}],
If[sec,{If[revarea,Blend[{Yellow,LightPurple}],LightOrange],Polygon[Prepend[Table[{t0,(.25Sin[2t0+1]+1) Sin[-θ],(.25Sin[2t0+1]+1) Cos[-θ]},{θ,0,2π,π/10}],{t0,0,0}]]},{}],
If[revrad,{{Blue,Text[Row[{"radius = ",Style["f",Italic],"(",Style["x",Italic],")"}],{t0,0,.25Sin[2t0+1]+1.5}]},{Blue,Thick,Line[{{t0,0,0},{t0,0,.25Sin[2t0+1]+1}}]}},{}]
}],curve2,comsolid2
},PlotRange->{{0,4.5},{-2,2},{-1.3,2.5}},
AxesOrigin->{0,0,0},Boxed->False,Axes->{None,None,Automatic},ViewPoint->{1.5,-4,0},Background->White,ImageSize->450,Ticks->{{1,4},None,None},BaseStyle->14],
{{sec,True,Column[{"cross","section"}]},{False,True}},
{{t0,2.5," "},1,4,ImageSize->Tiny,Enabled->sec},
"\n",
{{revrad,False,Column[{"radius"}]},{False,True}},
{{revarea,False,Column[{"area"}]},{False,True}},
{{revvol,False,Column[{"volume"}]},{False,True}},
ControlPlacement->Left,
Initialization:>(curve2=ParametricPlot3D[{x,0,.25Sin[2x+1]+1},{x,.5,4.5},PlotStyle->{RGBColor[0,0,0],AbsoluteThickness[1.75]}];
comsolid2=RevolutionPlot3D[.25Sin[2t+1]+1,{t,1,4},{θ,0,2π},RevolutionAxis->{1,0,0},PerformanceGoal->"Quality",Mesh->None,PlotStyle->Opacity[.3]];
leftend={Opacity[.3],Polygon[Prepend[Table[{1,(.25Sin[3]+1) Sin[-θ],(.25Sin[3]+1) Cos[-θ]},{θ,0,2π,π/12}],{1,0,0}]]};
rightend={Opacity[.3],Polygon[Prepend[Table[{4,(.25Sin[9]+1) Sin[-θ],(.25Sin[9]+1) Cos[-θ]},{θ,0,2π,π/12}],{4,0,0}]]}),
SaveDefinitions->True]

CAPTION

This Demonstration shows a concise step-by-step derivation of the disk method.

The general formula for the volume of a solid is (∫_a^b)A(x)dx where A(x) is the area of a cross section of the solid. In the case of the solid above, the cross section is a circle with area π ((f(x))^2).

THIS NOTEBOOK IS THE SOURCE CODE FROM

"The Disk Method" from the Wolfram Demonstrations Project
 http://demonstrations.wolfram.com/TheDiskMethod/

Contributed by: Lyle Cochran

A full-function Wolfram Mathematica system (Version 6 or higher) is required to edit this notebook.
GET WOLFRAM MATHEMATICA »

© Wolfram Demonstrations Project & Contributors   |   Terms of Use   |   Make a new version of this Demonstration »